Test reads device ID out of system config

[syncthing-autoregister] / tests / automatic-enrollment.nix

import <nixpkgs/nixos/tests/make-test-python.nix> ({ pkgs, lib, ... }:
  let
    configuration = pkgs.writeText "configuration.nix" ''
      { pkgs, ... }: {
        imports = [
          ${../.}/modules/syncthing-autoregister.nix
          <nixos/nixos/modules/installer/cd-dvd/channel.nix>
        ];
        services.syncthing = {
          enable = true;
          openDefaultPorts = true;
          autoRegister = {
            enable = true;
            path = "/tmp/syncthing-auto-register-test-device-ids.nix";
          };
        };
        environment.systemPackages = with pkgs; [ nix ];
      }
    '';
    configurationWithDeviceIDs = pkgs.writeText "configuration-with-device-ids.nix" ''
      {
        imports = [
          ${configuration}
          /tmp/syncthing-auto-register-test-device-ids.nix
        ];
      }
    '';
  in {

    name = "syncthing";

    machine = "${configuration}";

    testScript = ''
      machine.copy_from_host(
          "${configuration}",
          "/etc/nixos/configuration.nix",
      )
      machine.wait_for_unit("syncthing-autoregister.service")
      machine.copy_from_host(
          "${configurationWithDeviceIDs}",
          "/etc/nixos/configuration.nix",
      )
      machine.succeed(
          '(( "$(nix eval --raw -f "<nixos/nixos>" config.services.syncthing.declarative.devices.machine.id | wc -c)" == 63 ))'
      )
    '';
  })