git.scottworley.com Git - pinch/blob - default.nix

   1 { pkgs ? import <nixpkgs> { }, lint ? false }:
   2
   3 let
   4   checkInputsAreNative = pkgs.lib.hasInfix "nativeCheckInputs"
   5     (builtins.readFile <nixpkgs/doc/stdenv/stdenv.chapter.md>);
   6   checkInputsName =
   7     if checkInputsAreNative then "nativeCheckInputs" else "checkInputs";
   8
   9   git-cache-fallback =
  10     { buildPythonPackage, setuptools, fetchgit, git, backoff, mypy, }:
  11     buildPythonPackage rec {
  12       pname = "git-cache";
  13       version = "1.5.0";
  14       src = fetchgit {
  15         url = "https://git.scottworley.com/pub/git/git-cache";
  16         rev = "v${version}";
  17         hash = "sha256-g4TS/zX3e29Q3ThsCAX2wLLlYbi8fdux5uqAc+b/Oww=";
  18       };
  19       pyproject = true;
  20       build-system = [ setuptools ];
  21       propagatedBuildInputs = [ backoff ];
  22       "${checkInputsName}" = [ git mypy ];
  23       doCheck = true;
  24       checkPhase = "./test.sh";
  25     };
  26
  27 in pkgs.python3Packages.callPackage ({ lib, buildPythonPackage, setuptools, nix
  28   , git, autopep8, mypy, pylint, git-cache, }:
  29   buildPythonPackage rec {
  30     pname = "pinch";
  31     version = "3.3.2";
  32     src = lib.cleanSource ./.;
  33     pyproject = true;
  34     build-system = [ setuptools ];
  35     propagatedBuildInputs = [ git-cache ];
  36     "${checkInputsName}" = [ nix git mypy ]
  37       ++ lib.optionals lint [ autopep8 pylint ];
  38     doCheck = true;
  39     checkPhase = "./test.sh";
  40     meta = {
  41       description = "A replacement for `nix-channel --update`";
  42       homepage = "https://git.scottworley.com/pinch";
  43       license = pkgs.lib.licenses.gpl3;
  44       maintainers = with pkgs.lib.maintainers; [ chkno ];
  45     };
  46   }) {
  47     git-cache =
  48       pkgs.python3Packages.git-cache or (pkgs.python3Packages.callPackage
  49         git-cache-fallback { });
  50   }