client: Build in a Debian VM

[tattlekey] / client / default.nix

{ pkgs ? import <nixpkgs> { }, }:
let

  tattlekey = { lib, stdenv, cmake, pico-sdk, python3 }:
    stdenv.mkDerivation {
      pname = "tattlekey";
      version = "0.0.1";
      src = lib.cleanSource ./.;
      nativeBuildInputs = [ cmake python3 ];
      cmakeFlags = [
        "-DCMAKE_C_COMPILER=/usr/bin/arm-none-eabi-gcc"
        "-DCMAKE_CXX_COMPILER=/usr/bin/arm-none-eabi-c++"
        "-DPICO_BOARD=pico_w"
        "-DPICO_SDK_PATH=${pico-sdk}/lib/pico-sdk"
      ];
      diskImage = debImage;
      diskImageFormat = "qcow2";
    };

  pico-sdk = pkgs.pico-sdk.overrideAttrs (old: rec {
    version = "1.5.1";
    src = pkgs.fetchFromGitHub {
      fetchSubmodules = true;
      owner = "raspberrypi";
      repo = "pico-sdk";
      rev = version;
      hash = "sha256-GY5jjJzaENL3ftuU5KpEZAmEZgyFRtLwGVg3W1e/4Ho=";
    };
  });

  distro = "debian11x86_64";

  extraPackages = [
    "build-essential"
    "cmake"
    "gcc-arm-none-eabi"
    "libnewlib-arm-none-eabi"
    "libstdc++-arm-none-eabi-newlib"
  ];

  debImage = pkgs.vmTools.diskImageFuns."${distro}" { inherit extraPackages; };

in pkgs.vmTools.runInLinuxImage
(pkgs.callPackage tattlekey { pico-sdk = pico-sdk; })