{ pkgs ? import <nixpkgs> { }, lint ? false }:

let

  # Remove after https://github.com/NixOS/nixpkgs/pull/93377 reaches stable
  backoff-fallback = { lib, buildPythonPackage, fetchFromGitHub, pytestCheckHook
    , poetry, pytest-asyncio, }:
    buildPythonPackage rec {
      pname = "backoff";
      version = "1.10.0";
      src = fetchFromGitHub {
        owner = "litl";
        repo = pname;
        rev = "v${version}";
        sha256 = "1jj0l6pjx747d2yyvnzd3qbm4qr73sq6cc56dhvd8wqfbp5279x0";
      };
      format = "pyproject";
      nativeBuildInputs = [ poetry ];
      checkInputs = [ pytestCheckHook pytest-asyncio ];
    };

  git-cache-fallback = { buildPythonPackage, fetchgit, git, backoff, mypy, }:
    buildPythonPackage rec {
      pname = "git-cache";
      version = "1.4.1";
      src = fetchgit {
        url = "https://git.scottworley.com/pub/git/git-cache";
        rev = "v${version}";
        sha256 = "0ml1myhmd9mw1z5bwni9fhvx7h9dknhmqq4nyci9n5lvrhbmcdc9";
      };
      propagatedBuildInputs = [ backoff ];
      checkInputs = [ git mypy ];
      doCheck = true;
      checkPhase = "./test.sh";
    };

in pkgs.python3Packages.callPackage ({ lib, buildPythonPackage, nix_2_3, git
  , autopep8, makeWrapper, mypy, pylint, git-cache, }:
  buildPythonPackage rec {
    pname = "pinch";
    version = "3.0.9-pre";
    src = lib.cleanSource ./.;
    buildInputs = [ makeWrapper ];
    propagatedBuildInputs = [ git-cache ];
    checkInputs = [ nix_2_3 git mypy ] ++ lib.optionals lint [ autopep8 pylint ];
    postInstall = ''
      wrapProgram "$out/bin/pinch" --prefix PATH : ${nix_2_3}/bin
    '';
    doCheck = true;
    checkPhase = "./test.sh";
  }) {
    git-cache =
      pkgs.python3Packages.git-cache or (pkgs.python3Packages.callPackage
        git-cache-fallback {
          backoff =
            pkgs.python3Packages.backoff or (pkgs.python3Packages.callPackage
              backoff-fallback { });
        });
    nix_2_3 = pkgs.nix_2_3 or pkgs.nix;
  }