{ pkgs ? import <nixpkgs> { }, lint ? false }:

let

  # Remove after https://github.com/NixOS/nixpkgs/pull/93377 reaches stable
  backoff-fallback = { lib, buildPythonPackage, fetchFromGitHub, pytestCheckHook
    , poetry, pytest-asyncio, }:
    buildPythonPackage rec {
      pname = "backoff";
      version = "1.10.0";
      src = fetchFromGitHub {
        owner = "litl";
        repo = pname;
        rev = "v${version}";
        sha256 = "1jj0l6pjx747d2yyvnzd3qbm4qr73sq6cc56dhvd8wqfbp5279x0";
      };
      format = "pyproject";
      nativeBuildInputs = [ poetry ];
      checkInputs = [ pytestCheckHook pytest-asyncio ];
    };

  git-cache-fallback = { buildPythonPackage, fetchgit, git, backoff, mypy, }:
    buildPythonPackage rec {
      pname = "git-cache";
      version = "1.3.1";
      src = fetchgit {
        url = "https://scottworley.com/git-cache.git";
        rev = "v${version}";
        sha256 = "0awz7f6avzw9fk9gp1kadj0nbmf1s60qic9zb6ww92zig3khg12k";
      };
      propagatedBuildInputs = [ backoff ];
      checkInputs = [ git mypy ];
      doCheck = true;
      checkPhase = "./test.sh";
    };

in pkgs.python3Packages.callPackage ({ lib, buildPythonPackage, nix, git
  , autopep8, makeWrapper, mypy, pylint, git-cache, }:
  buildPythonPackage rec {
    pname = "pinch";
    version = "3.0.4";
    src = lib.cleanSource ./.;
    buildInputs = [ makeWrapper ];
    propagatedBuildInputs = [ git-cache ];
    checkInputs = [ nix git mypy ] ++ lib.optionals lint [ autopep8 pylint ];
    postInstall = ''
      wrapProgram "$out/bin/pinch" --prefix PATH : ${nix}/bin
    '';
    doCheck = true;
    checkPhase = "./test.sh";
  }) {
    git-cache =
      pkgs.python3Packages.git-cache or (pkgs.python3Packages.callPackage
        git-cache-fallback {
          backoff =
            pkgs.python3Packages.backoff or (pkgs.python3Packages.callPackage
              backoff-fallback { });
        });
  }