{ pkgs ? import <nixpkgs> { }, lint ? false }:

let
  checkInputsAreNative = pkgs.lib.hasInfix "nativeCheckInputs"
    (builtins.readFile <nixpkgs/doc/stdenv/stdenv.chapter.md>);
  checkInputsName =
    if checkInputsAreNative then "nativeCheckInputs" else "checkInputs";

  git-cache-fallback = { buildPythonPackage, fetchgit, git, backoff, mypy, }:
    buildPythonPackage rec {
      pname = "git-cache";
      version = "1.5.0";
      src = fetchgit {
        url = "https://git.scottworley.com/pub/git/git-cache";
        rev = "v${version}";
        hash = "sha256-g4TS/zX3e29Q3ThsCAX2wLLlYbi8fdux5uqAc+b/Oww=";
      };
      propagatedBuildInputs = [ backoff ];
      "${checkInputsName}" = [ git mypy ];
      doCheck = true;
      checkPhase = "./test.sh";
    };

in pkgs.python3Packages.callPackage
({ lib, buildPythonPackage, nix, git, autopep8, mypy, pylint, git-cache, }:
  buildPythonPackage rec {
    pname = "pinch";
    version = "3.3.1";
    src = lib.cleanSource ./.;
    propagatedBuildInputs = [ git-cache ];
    "${checkInputsName}" = [ nix git mypy ]
      ++ lib.optionals lint [ autopep8 pylint ];
    doCheck = true;
    checkPhase = "./test.sh";
    meta = {
      description = "A replacement for `nix-channel --update`";
      homepage = "https://git.scottworley.com/pinch";
      license = pkgs.lib.licenses.gpl3;
      maintainers = with pkgs.lib.maintainers; [ chkno ];
    };
  }) {
    git-cache =
      pkgs.python3Packages.git-cache or (pkgs.python3Packages.callPackage
        git-cache-fallback { });
  }