Move git_cache out to a separate library

[pinch] / default.nix

{ pkgs ? import <nixpkgs> { }, lint ? false }:

let
  git-cache-fallback = { buildPythonPackage, fetchgit, git, mypy, }:
    buildPythonPackage rec {
      pname = "git-cache";
      version = "1.0.0";
      src = fetchgit {
        url = "https://scottworley.com/git-cache.git";
        rev = "v${version}";
        sha256 = "06mzjc424988n2s1h25x2bi3mxbk2pnba31zkjljgw4cgw2p9036";
      };
      checkInputs = [ git mypy ];
      doCheck = true;
      checkPhase = "./test.sh";
    };

in pkgs.python3Packages.callPackage
({ lib, buildPythonPackage, nix, git, autopep8, mypy, pylint, git-cache, }:
  buildPythonPackage rec {
    pname = "pinch";
    version = "3.0.0-pre";
    src = lib.cleanSource ./.;
    propagatedBuildInputs = [ git-cache ];
    checkInputs = [ nix git mypy ] ++ lib.optionals lint [ autopep8 pylint ];
    doCheck = true;
    checkPhase = "./test.sh";
  }) {
    git-cache =
      pkgs.python3Packages.git-cache or (pkgs.python3Packages.callPackage
        git-cache-fallback { });
  }