Fix a bash-ism in test.sh, which is #!/bin/sh

[pinch] / default.nix

{ pkgs ? import <nixpkgs> { }, lint ? false }:

let
  checkInputsAreNative = pkgs.lib.hasInfix "nativeCheckInputs"
    (builtins.readFile <nixpkgs/doc/stdenv/stdenv.chapter.md>);
  checkInputsName =
    if checkInputsAreNative then "nativeCheckInputs" else "checkInputs";

  git-cache-fallback = { buildPythonPackage, fetchgit, git, backoff, mypy, }:
    buildPythonPackage rec {
      pname = "git-cache";
      version = "1.4.3";
      src = fetchgit {
        url = "https://git.scottworley.com/pub/git/git-cache";
        rev = "v${version}";
        hash = "sha256-Qr62bGdlFFkzYTl6ot34UiOJxbP1Eeelx2OEd96vrqI=";
      };
      propagatedBuildInputs = [ backoff ];
      "${checkInputsName}" = [ git mypy ];
      doCheck = true;
      checkPhase = "./test.sh";
    };

in pkgs.python3Packages.callPackage ({ lib, buildPythonPackage, nix_2_3, git
  , autopep8, makeWrapper, mypy, pylint, git-cache, }:
  buildPythonPackage rec {
    pname = "pinch";
    version = "3.0.15-pre";
    src = lib.cleanSource ./.;
    buildInputs = [ makeWrapper ];
    propagatedBuildInputs = [ git-cache ];
    "${checkInputsName}" = [ nix_2_3 git mypy ]
      ++ lib.optionals lint [ autopep8 pylint ];
    postInstall = ''
      wrapProgram "$out/bin/pinch" --prefix PATH : ${nix_2_3}/bin
    '';
    doCheck = true;
    checkPhase = "./test.sh";
    meta = {
      description = "A replacement for `nix-channel --update`";
      homepage = "https://git.scottworley.com/pinch";
      license = pkgs.lib.licenses.gpl3;
      maintainers = with pkgs.lib.maintainers; [ chkno ];
    };
  }) {
    git-cache =
      pkgs.python3Packages.git-cache or (pkgs.python3Packages.callPackage
        git-cache-fallback { });
    nix_2_3 = pkgs.nix_2_3 or pkgs.nix;
  }