git.scottworley.com Git - nix-env-apps/blob - default.nix

   1 { pkgs ? import <nixpkgs> { }, lint ? false }:
   2 pkgs.python3Packages.callPackage ({ autopep8, buildPythonPackage
   3   , gobject-introspection, gtk4, lib, makeDesktopItem, mypy, pylint, pygobject3
   4   , wrapGAppsHook4, }:
   5   buildPythonPackage rec {
   6     pname = "apps";
   7     version = "1.0.1";
   8
   9     src = lib.cleanSource ./.;
  10
  11     doCheck = true;
  12     checkPhase = "./test.sh";
  13
  14     nativeBuildInputs = [ gobject-introspection wrapGAppsHook4 ];
  15     nativeCheckInputs = [ mypy ] ++ lib.optionals lint [ autopep8 pylint ];
  16     buildInputs = [ gtk4 ];
  17     pythonPath = [ pygobject3 ];
  18
  19     postInstall = ''
  20       cp -r $desktopItem/share $out
  21     '';
  22
  23     desktopItem = makeDesktopItem {
  24       name = "Apps";
  25       exec = "apps";
  26       icon = ./apps.png;
  27       comment = "Configure nix-env Apps";
  28       desktopName = "Apps";
  29       genericName = "Configure Apps";
  30       categories = [ "Settings" ];
  31     };
  32
  33     meta = {
  34       description =
  35         "A simple GUI for managing declarative nix-env user environments";
  36       homepage = "https://git.scottworley.com/nix-env-apps";
  37       license = pkgs.lib.licenses.gpl3;
  38       maintainers = with pkgs.lib.maintainers; [ chkno ];
  39     };
  40
  41   }) { }