X-Git-Url: http://git.scottworley.com/auto-upgrade-with-pinch/blobdiff_plain/4ed6fe195d49b7e9cfe087cbce799db8998d1e60..HEAD:/overlays/pinch.nix

diff --git a/overlays/pinch.nix b/overlays/pinch.nix
index 1b2c65f..37c2e7d 100644
--- a/overlays/pinch.nix
+++ b/overlays/pinch.nix
@@ -1,9 +1,44 @@
-self: super: {
-  pinch = super.writeShellScriptBin "pinch" ''
-    exec ${self.python3}/bin/python3 ${super.fetchgit {
-      url = "https://scottworley.com/pinch.git";
-      rev = "1.1";
-      sha256 = "0ilbhvr0d83kfwkm7ak64gik44gi2axfnp9rzsa7g5cwz9qaxdbv";
-    }}/pinch.py "$@"
-  '';
-}
+self: super:
+let
+  checkInputsAreNative = self.lib.hasInfix "nativeCheckInputs"
+    (builtins.readFile <nixpkgs/doc/stdenv/stdenv.chapter.md>);
+  checkInputsName =
+    if checkInputsAreNative then "nativeCheckInputs" else "checkInputs";
+
+  fallback-git-cache = self.python3Packages.callPackage
+    ({ buildPythonPackage, fetchgit, git, backoff, mypy, }:
+      buildPythonPackage rec {
+        pname = "git-cache";
+        version = "1.5.0";
+        src = fetchgit {
+          url = "https://git.scottworley.com/pub/git/git-cache";
+          rev = "v${version}";
+          hash = "sha256-g4TS/zX3e29Q3ThsCAX2wLLlYbi8fdux5uqAc+b/Oww=";
+        };
+        propagatedBuildInputs = [ backoff ];
+        "${checkInputsName}" = [ git mypy ];
+        doCheck = true;
+        checkPhase = "./test.sh";
+      }) { };
+
+  fallback-pinch = self.python3Packages.callPackage
+    ({ buildPythonPackage, fetchgit, nix_2_3, git, makeWrapper, mypy, git-cache, }:
+      buildPythonPackage rec {
+        pname = "pinch";
+        version = "3.1.0";
+        src = fetchgit {
+          url = "https://git.scottworley.com/pub/git/pinch";
+          rev = "v${version}";
+          hash = "sha256-qwbYDSGE6p1YU3AnOatXNoTUc284D1xPQs/tRS++VOM=";
+        };
+        buildInputs = [ makeWrapper ];
+        propagatedBuildInputs = [ git-cache ];
+        "${checkInputsName}" = [ nix_2_3 git mypy ];
+        postInstall = ''
+          wrapProgram "$out/bin/pinch" --prefix PATH : ${nix_2_3}/bin
+        '';
+        doCheck = true;
+        checkPhase = "./test.sh";
+      }) { git-cache = self.python3Packages.git-cache or fallback-git-cache; };
+
+in { pinch = super.pinch or fallback-pinch; }