X-Git-Url: http://git.scottworley.com/auto-upgrade-with-pinch/blobdiff_plain/4ed6fe195d49b7e9cfe087cbce799db8998d1e60..752d37291d831f952f4998e75b4180a4690fc979:/overlays/pinch.nix?ds=inline

diff --git a/overlays/pinch.nix b/overlays/pinch.nix
index 1b2c65f..546ccdc 100644
--- a/overlays/pinch.nix
+++ b/overlays/pinch.nix
@@ -1,9 +1,66 @@
-self: super: {
-  pinch = super.writeShellScriptBin "pinch" ''
-    exec ${self.python3}/bin/python3 ${super.fetchgit {
-      url = "https://scottworley.com/pinch.git";
-      rev = "1.1";
-      sha256 = "0ilbhvr0d83kfwkm7ak64gik44gi2axfnp9rzsa7g5cwz9qaxdbv";
-    }}/pinch.py "$@"
-  '';
+self: super:
+let
+  fallback-git-cache = self.python3Packages.callPackage (
+    {
+      buildPythonPackage,
+      fetchgit,
+      setuptools,
+      git,
+      backoff,
+      mypy,
+    }:
+    buildPythonPackage rec {
+      pname = "git-cache";
+      version = "1.5.0";
+      src = fetchgit {
+        url = "https://git.scottworley.com/pub/git/git-cache";
+        rev = "v${version}";
+        hash = "sha256-g4TS/zX3e29Q3ThsCAX2wLLlYbi8fdux5uqAc+b/Oww=";
+      };
+      pyproject = true;
+      build-system = [ setuptools ];
+      propagatedBuildInputs = [ backoff ];
+      nativeCheckInputs = [
+        git
+        mypy
+      ];
+      doCheck = true;
+      checkPhase = "./test.sh";
+    }
+  ) { };
+
+  fallback-pinch = self.python3Packages.callPackage (
+    {
+      buildPythonPackage,
+      fetchgit,
+      setuptools,
+      nix,
+      git,
+      mypy,
+      git-cache,
+    }:
+    buildPythonPackage rec {
+      pname = "pinch";
+      version = "3.3.3";
+      src = fetchgit {
+        url = "https://git.scottworley.com/pub/git/pinch";
+        rev = "v${version}";
+        hash = "sha256-+SdKvGPofOJn0lBOSP4SH3i2WGpBuEXmLzzpYD1epgc=";
+      };
+      pyproject = true;
+      build-system = [ setuptools ];
+      propagatedBuildInputs = [ git-cache ];
+      nativeCheckInputs = [
+        nix
+        git
+        mypy
+      ];
+      doCheck = true;
+      checkPhase = "./test.sh";
+    }
+  ) { git-cache = self.python3Packages.git-cache or fallback-git-cache; };
+
+in
+{
+  pinch = super.pinch or fallback-pinch;
 }