self: super:
let
  fallback-git-cache = self.python3Packages.callPackage
    ({ buildPythonPackage, fetchgit, git, backoff, mypy, }:
      buildPythonPackage rec {
        pname = "git-cache";
        version = "1.5.0";
        src = fetchgit {
          url = "https://git.scottworley.com/pub/git/git-cache";
          rev = "v${version}";
          hash = "sha256-g4TS/zX3e29Q3ThsCAX2wLLlYbi8fdux5uqAc+b/Oww=";
        };
        propagatedBuildInputs = [ backoff ];
        nativeCheckInputs = [ git mypy ];
        doCheck = true;
        checkPhase = "./test.sh";
      }) { };

  fallback-pinch = self.python3Packages.callPackage
    ({ buildPythonPackage, fetchgit, nix_2_3, git, makeWrapper, mypy, git-cache, }:
      buildPythonPackage rec {
        pname = "pinch";
        version = "3.1.0";
        src = fetchgit {
          url = "https://git.scottworley.com/pub/git/pinch";
          rev = "v${version}";
          hash = "sha256-qwbYDSGE6p1YU3AnOatXNoTUc284D1xPQs/tRS++VOM=";
        };
        buildInputs = [ makeWrapper ];
        propagatedBuildInputs = [ git-cache ];
        nativeCheckInputs = [ nix_2_3 git mypy ];
        postInstall = ''
          wrapProgram "$out/bin/pinch" --prefix PATH : ${nix_2_3}/bin
        '';
        doCheck = true;
        checkPhase = "./test.sh";
      }) { git-cache = self.python3Packages.git-cache or fallback-git-cache; };

in { pinch = super.pinch or fallback-pinch; }