git.scottworley.com Git - auto-upgrade-with-pinch/blob - overlays/pinch.nix

   1 self: super:
   2 let
   3
   4   # Pending upstream inclusion in https://github.com/NixOS/nixpkgs/pull/93377
   5   fallback-backoff = self.python3Packages.callPackage ({ lib, buildPythonPackage
   6     , fetchFromGitHub, pytestCheckHook, poetry, pytest-asyncio, }:
   7     buildPythonPackage rec {
   8       pname = "backoff";
   9       version = "1.10.0";
  10       src = fetchFromGitHub {
  11         owner = "litl";
  12         repo = pname;
  13         rev = "v${version}";
  14         sha256 = "1jj0l6pjx747d2yyvnzd3qbm4qr73sq6cc56dhvd8wqfbp5279x0";
  15       };
  16       format = "pyproject";
  17       nativeBuildInputs = [ poetry ];
  18       checkInputs = [ pytestCheckHook pytest-asyncio ];
  19     }) { };
  20
  21   fallback-git-cache = self.python3Packages.callPackage
  22     ({ buildPythonPackage, fetchgit, git, backoff, mypy, }:
  23       buildPythonPackage rec {
  24         pname = "git-cache";
  25         version = "1.3.1";
  26         src = fetchgit {
  27           url = "https://git.scottworley.com/pub/git/git-cache";
  28           rev = "v${version}";
  29           sha256 = "0awz7f6avzw9fk9gp1kadj0nbmf1s60qic9zb6ww92zig3khg12k";
  30         };
  31         propagatedBuildInputs = [ backoff ];
  32         checkInputs = [ git mypy ];
  33         doCheck = true;
  34         checkPhase = "./test.sh";
  35       }) { backoff = self.python3Packages.backoff or fallback-backoff; };
  36
  37   fallback-pinch = self.python3Packages.callPackage
  38     ({ buildPythonPackage, fetchgit, nix_2_3, git, makeWrapper, mypy, git-cache, }:
  39       buildPythonPackage rec {
  40         pname = "pinch";
  41         version = "3.0.9";
  42         src = fetchgit {
  43           url = "https://git.scottworley.com/pub/git/pinch";
  44           rev = "v${version}";
  45           sha256 = "sha256-D1XC8pmemdOpIEWvS0VH9Fguvp92FqpQfJj2TudfwRw=";
  46         };
  47         buildInputs = [ makeWrapper ];
  48         propagatedBuildInputs = [ git-cache ];
  49         checkInputs = [ nix_2_3 git mypy ];
  50         postInstall = ''
  51           wrapProgram "$out/bin/pinch" --prefix PATH : ${nix_2_3}/bin
  52         '';
  53         doCheck = true;
  54         checkPhase = "./test.sh";
  55       }) { git-cache = self.python3Packages.git-cache or fallback-git-cache; };
  56
  57 in { pinch = super.pinch or fallback-pinch; }