Accept multiple signing keys

[auto-upgrade-with-pinch] / overlays / keyedgit.nix

# Following the instructions at https://tribut.de/blog/git-commit-signatures-trusted-keys

self: super: {
  keyedgit = keys:
    let
      homelessGPG = super.writeShellScript "homeless-gpg" ''
        export GNUPGHOME=$(mktemp -d)
        trap 'rm -r "$GNUPGHOME"' EXIT
        ${self.gnupg}/bin/gpg "$@"
      '';
      keyring = super.runCommand "keyedkeyring.gpg" {} ''
        ${homelessGPG} --no-default-keyring --keyring=$out --import ${keys}
      '';
      keyids = super.runCommand "keyids" {} ''
        ${homelessGPG} --no-default-keyring --with-colons --show-keys ${keys} |
          ${self.gawk}/bin/awk -F: 'prev == "pub" && $1 == "fpr" { print $10 } { prev = $1 }' > $out
      '';
      keyedGPG = super.writeShellScript "keyed-gpg" ''
        trusted_key_args=()
        while read keyid;do
          trusted_key_args+=( --trusted-key "$keyid" )
        done < ${keyids}
        ${homelessGPG} --no-default-keyring --keyring=${keyring} "''${trusted_key_args[@]}" "$@"
      '';
    in super.symlinkJoin {
      name = "keyedgit";
      paths = [ self.git ];
      buildInputs = [ super.makeWrapper ];
      postBuild = ''
        wrapProgram "$out/bin/git" \
          --add-flags '-c gpg.program=${keyedGPG}'
      '';
    };
}